Carlos (@cj_beas):

 

Este invento que realicé hace años, consistía básicamente en la utilización de un guante de cocina, con dos clips y una fotorresistencia (LDR), conectados al puerto del joystick, pero originalmente el proyecto lo hice sobre un Vic-20. Luego creé un programa en basic que consistía en mover un caracter, de un lado al otro de la pantalla, con sonido que variaba mientras cambiaba de posición.

Ahora para recrear de nuevo el proyecto he utilizado un C64 y el WinVice, ya que actualmente no dispongo del Vic20.

 

Los materiales que he utilizado son:

• Guante de cocina o similar
• 2 Clips
• Una resistencia de 330 ohmios (Ω)
• Una fotoresistencia LDR (valor desconocido)
• Cableado
• Conector DB9 hembra (9 pines)

 

Tras buscar de nuevo información para recuperar la memoria de aquel trabajo, he usado varios documentos para orientarme:

• Descripción de los pines del joystick
• Descripción de un Paddle y un ejemplo de lectura de sus valores
• Información del puerto de juegos
• Commodore World nº 23 – “Construye tu joystick” Trata el puerto de juegos pero solo la entrada de joystick no la de paddles.
• Commodore World nº 54 –  “Digitalizador C-128” (Otro interesante invento con el puerto de juegos)
• Input Commodore nº18 –  “El C64 como estación meteorológica” (Aquí se habla de varias formas de usar las entradas analógicas).
• Input Commodore nº8  – “El SID: Un maravilloso ruidoso” (Aquí se curiosea con otra forma de introducir datos analógicos en el SID)

 

Con esto he creado el esquema de trabajo a desarrollar:

 

El “SW” es un interruptor, que en este caso lo he sustituido por los dos clips colocados cada uno en un dedo diferente, este ocupa el Joy A1 (Dirección abajo). Y al juntar los dedos (pulgar e indice) cierro el circuito.

La resistencia de 330 omhios sirve para proteger el chip SID de daños no deseados.

“LDR”, es la fotoresistencia, que en este caso es una que disponía pero desconozco su valor. Esta va pegada con cinta aislante al extremo del dedo meñique, para que al mover este, o la mano, controlemos un valor analógico, (entre 0 y 255). Para que al conectarlo al pin 5 le corresponda el POT AY (Eje y de paddle).

 

Este sería el resultado del guante:

 

El siguiente paso era comprobar el montaje, para ello usé este pequeño programa.

10 PRINT”JOY:”PEEK(56321)
20 PRINT”POT Y:”PEEK(54297)
30 GOTO 10

Descarga del Test

 

A continuación, con el WinVice termine de crear el resto.

(Para crear el programa completo, he utilizado el manual de usuario para programar el sonido y fusilar el código del sprite de la página 70).

 

El programa resultante es este:

90 rem nota voz3
100 poke54287,17: rem poke54272,37
150 print chr$(147)
160 v = 53248 : rem start of display chip
170 poke v + 21,4 : rem enable sprite 2
180 poke 2042,13 : rem sprite 2 data from block 13
190 for n = 0 to 62 : read q : poke 832+n,q : next
200 data 0,127,0,1,255,192,3,255,224,3,231,224
210 data 7,217,240,7,223,240,7,217,240,3,231,224
220 data 3,255,224,3,255,224,2,255,160,1,127,64
230 data 1,62,64,0,156,128,0,156,128,0,73,0,0,73,0
240 data 0,62,0,0,62,0,0,62,0,0,28,0
299 rem switches the POT lines to read from control port 1
300 poke56320,64
490 rem envovente triangulo
500 poke 54276,17
590 rem duracion
600 fort=1to250:next
690 rem audio off
700 rem poke 54276,0
1000 for x = 0 to 200
1100 poke v + 4,peek(54272+25) : rem Pot Y mueve en X
1200 poke v + 5,x : rem cae
1250 if peek(56321)<>255 then gosub2000:rem Joy down
1290 poke 54272+1,peek(54272+25):rem sonido segun Pot Y
1300 next x
1400 goto 1000
2000 fort=1to50:poke 53280,t:next:poke53280,6:rem borde rafaga
2050 rem envovente triangulo
2060 poke 54290,129
2070 rem duracion
2080 fort=1to250:next
2090 poke 54290,0
2100 return

 

Descarga del programa

 

Detalles del DATAGLOVE

 

Como podéis ver, esta versión del dataglove del C64 es bastante casera, pero es de suponer que con más medios y mejores acabados se podría crear una versión más profesional, Así que si alguien se anima, aquí tiene la idea, el resto es cosa vuestra.

 

El resultado de todo lo podéis ver en este vídeo que he creado para la ocasión